Français TaskForce Radio Check

[Max3107]

toujours le meme problème ^^

 

[Maximux]

tu peu transmettre la partis modif de ton init
stp

 

[Maxence]

Pour voir ce que ça donne dans la debug console il faut mettre le code ici :

 

[Max3107]

Pour voir ce que ça donne dans la debug console il faut mettre le code ici :
Voir la pièce jointe 4028

Bonjour Maxence, sa me fait rien de plus

 

[Maximux]

tu peu transmettre la partis modif de ton init
stp

 

[Max3107]

Voici ; ^^



[CODE title="."][] spawn {
_teamspeakName = "Eléor RP";
_temspeakAdress = "eleorrp.tslu3.xyz";
_channelName = "TASKFORCERADIO";
_kickAfter = 30; // Nombre de secondes après lequel kicker le joueur s'il n'est toujours pas sur Teamspeak

// Editing code below is not recommended
_isAdmin = false;
if !(isNil "life_adminlevel") then {
if ((call life_adminlevel) > 0) then {
_isAdmin = true;
titleText ["La vérification de présence dans le canal Task Force Radio est désactivé comme vous êtes admin !","BLACK IN"];
};
};
if (_isAdmin) exitWith {};

if (isNil "TFAR_fnc_isTeamSpeakPluginEnabled") exitwith {
999999 cutText ["Task Force Radio n'est pas activé pas sur votre ordinateur. Veuillez re-synchroniser et réessayer","BLACK FADED"];
999999 cutFadeOut 99999999;
};

_tfarEnabled = true;
_playerOnTeamspeak = true;
_playerInChannel = false;
_sleep = 2;
_timeout = _kickAfter;
_alreadyKnow = false;

while {true} do {
if !([] call TFAR_fnc_isTeamSpeakPluginEnabled) then {
titleText ["Veuillez activer Task Force Radio dans vos plugins teamspeak ! Pour ce faire, rendez-vous dans l'onglet réglages de teamspeak puis plugins et activez-le.", "BLACK"];
_tfarEnabled = false;
} else {
_tfarEnabled = true;
};

if !(_teamspeakName == (call TFAR_fnc_getTeamSpeakServerName)) then {
titleText [format ["Veuillez rejoindre notre teamspeak : %1",_temspeakAdress], "BLACK"];
_playerOnTeamspeak = false;
} else {
_playerOnTeamspeak = true;
};

if !(_channelName == (call TFAR_fnc_getTeamSpeakChannelName)) then {
titleText ["Veuillez 'reload' votre plugin Task Force Radio pour être déplacer dans le canal vocal ! Pour ce faire rendez-vous dans les réglages de teamspeak puis plugins puis appuyez sur le bouton 'relaod'.", "BLACK"];
_playerInChannel = false;
} else {
_playerInChannel = true;
};

if (_tfarEnabled && _playerOnTeamspeak && _playerInChannel) then {
if !(_alreadyKnow) then {
titleText ["Task Force Radio est bien initialisé, bienvenue !","BLACK IN"];
_alreadyKnow = true;
};
_sleep = 5;
} else {
_alreadyKnow = false;
_sleep = 2;
};

sleep _sleep;

if (!_tfarEnabled || !_playerOnTeamspeak || !_playerInChannel) then {
_timeout = _timeout - _sleep;
} else {
_timeout = _kickAfter;
};

if (_timeout <= 0) exitwith {};
};

if (_timeout <= 0) then {
["Teamspeak",false,false] call BIS_fnc_endMission;
};
};[/CODE]

 

[Maximux]

_teamspeakName = "Eléor RP";
Ton ts ne s'appelle pas comme ça mes ELEOR

 

[Maximux]

J'ai vu que tu avais modifier, un petit retour pour dire si tout est ok.

 

[Max3107]

Problème regler merci à vous ! ^^