Français Enlever le marqueur GPS quand on n'a plus de GPS

[I'm the Boss]

Bonjour, dans ce petit tuto, je vais vous montrer comment faire, pour enlever le marqueur gps (Point sur la carte avec le nom de vos collègues policiers, pompiers, ou des gens présents dans le même groupe que vous), lorsqu'ils n'ont plus de GPS, et vous également.

• Allez à la racine de votre mission, puis allez dans le dossier core/civilian. Ensuite, ouvrez le fichier "fn_civMarkers.sqf" et remplacez l'intégralité du code par:

/*
    File: fn_civMarkers.sqf
    Author:

    Description:
    Add markers for civilians in groups.
*/
private ["_markers", "_members"];
_markers = [];
_members = [];

for "_i" from 0 to 1 step 0 do {
    sleep 0.5;
    if (visibleMap) then {
        _members = units (group player);
        {
            if (!(_x isEqualTo player) && ("ItemGPS" in (assignedItems _X)) && ("ItemGPS" in (assignedItems player))) then {
                _marker = createMarkerLocal [format ["%1_marker", _x], visiblePosition _x];
                _marker setMarkerColorLocal "ColorCivilian";
                _marker setMarkerTypeLocal "Mil_dot";
                _marker setMarkerTextLocal format ["%1", _x getVariable ["realname", name _x]];
                _markers pushBack [_marker, _x];
            };
        } forEach _members;

        while {visibleMap} do {
            {
                private ["_unit"];
                _unit = _x select 1;
                if (!isNil "_unit" && !isNull _unit) then {
                    (_x select 0) setMarkerPosLocal (visiblePosition _unit);
                };
            } forEach _markers;
            if (!visibleMap) exitWith { };
            sleep 0.02;
        };

        { deleteMarkerLocal (_x select 0); } forEach _markers;
        _markers = [];
        _members = [];
    };
};

• Allez à la racine de votre mission, puis allez dans le dossier core/medic. Ensuite, ouvrez le fichier "fn_medicMarkers.sqf" et remplacez l'intégralité du code par:

/*
    File: fn_medicMarkers.sqf
    Author: Bryan "Tonic" Boardwine

    Description:
    Marks downed players on the map when it's open.
*/
private ["_markers","_units","_medics"];
_markers = [];
_markersMedecin = [];
_units = [];
_medics = [];

sleep 0.25;
if (visibleMap) then {
    {if (side _x isEqualTo independent) then {_medics pushBack _x;}} forEach playableUnits; //Fetch list of cops / blufor
    {
        _name = _x getVariable "name";
        _down = _x getVariable ["Revive",false];
        if (!isNil "_name" && !_down) then {
            _units pushBack _x;
        };
    } forEach allDeadMen;

    {
        if (!(_x isEqualTo player) && ("ItemGPS" in (assignedItems _X)) && ("ItemGPS" in (assignedItems player))) then {
            _markerss = createMarkerLocal [format ["%1_marker",_x],visiblePosition _x];
            _markerss setMarkerColorLocal "ColorIndependent";
            _markerss setMarkerTypeLocal "Mil_dot";
            _markerss setMarkerTextLocal format ["%1", _x getVariable ["realname",name _x]];

            _markersMedecin pushBack [_markerss,_x];
        };
    } forEach _medics;

    //Loop through and create markers.
    {
        _marker = createMarkerLocal [format ["%1_dead_marker",_x],visiblePosition _x];
        _marker setMarkerColorLocal "ColorRed";
        _marker setMarkerTypeLocal "loc_Hospital";
        _marker setMarkerTextLocal format ["%1",(_x getVariable ["name","Unknown Player"])];
        _markers pushBack _marker;
    } forEach _units;

    while {visibleMap} do {
        {
            private ["_unit"];
            _unit = _x select 1;
            if (!isNil "_unit" && !isNull _unit) then {
                (_x select 0) setMarkerPosLocal (visiblePosition _unit);
            };
        } forEach _markersMedecin;
        if (!visibleMap) exitWith {};
        sleep 0.02;
    };
    {deleteMarkerLocal (_x select 0);} forEach _markersMedecin;
    _markersMedecin = [];
    _medics = [];
    waitUntil {!visibleMap};
    {deleteMarkerLocal _x;} forEach _markers;
};

• Allez à la racine de votre mission, puis allez dans le dossier core/cop. Ensuite, ouvrez le fichier "fn_copMarkers.sqf" et remplacez l'intégralité du code par:

/*
    File: fn_copMarkers.sqf
    Author: Bryan "Tonic" Boardwine

    Description:
    Marks cops on the map for other cops. Only initializes when the actual map is open.
*/
private ["_markers","_cops"];
_markers = [];
_cops = [];

sleep 0.5;
if (visibleMap) then {
    {if (side _x isEqualTo west) then {_cops pushBack _x;}} forEach playableUnits; //Fetch list of cops / blufor

    //Create markers
    {
        if (!(_x isEqualTo player) && ("ItemGPS" in (assignedItems _X)) && ("ItemGPS" in (assignedItems player))) then {
            _marker = createMarkerLocal [format ["%1_marker",_x],visiblePosition _x];
            _marker setMarkerColorLocal "ColorBLUFOR";
            _marker setMarkerTypeLocal "Mil_dot";
            _marker setMarkerTextLocal format ["%1", _x getVariable ["realname",name _x]];

            _markers pushBack [_marker,_x];
        };
    } forEach _cops;

    while {visibleMap} do {
        {
            private ["_unit"];
            _unit = _x select 1;
            if (!isNil "_unit" && !isNull _unit) then {
                (_x select 0) setMarkerPosLocal (visiblePosition _unit);
            };
        } forEach _markers;
        if (!visibleMap) exitWith {};
        sleep 0.02;
    };

    {deleteMarkerLocal (_x select 0);} forEach _markers;
    _markers = [];
    _cops = [];
};