Français Not solved Comment lier les factures au script de l'entreprise?

[Teravince]

Bonjour je souhaite savoir comme faire pour que les faction soit en relation avec le script entreprise, je souhaite faire en sorte que quand une personne paye une facture l'argent soit envoyer sur le compte de l'entreprise car celui ci sera réservé au entreprise.

 

[Maxence]

Salut ! Beaucoup de modifications à faire...

Dans ton @The_Programmer/addons/billing_system/client/fn_sendFacture.sqf, trouve ces lignes :

[1,(["STR_RECEIVE_NEW_FACTURE","Max_Settings_Facture","Facture_Localization"] call theprogrammer_core_fnc_localize)] remoteExecCall ["life_fnc_broadcast",_to];

[(getPlayerUID player),(getPlayerUID _to),_objet,_entreprise,_montant,(name _to)] remoteExec ["max_facture_fnc_insertFacture",2];

et remplace les par :

_realEntreprise = player getVariable ["current_entreprise",objNull];
if (isNull _realEntreprise) exitWith {hint "Vous n'avez pas d'entreprise, vous ne pouvez pas envoyer de facture !";};
_id = _realEntreprise getVariable ["entreprise_id",-1];
if (_id isEqualTo -1) exitWith {hint "Vous n'avez pas d'entreprise, vous ne pouvez pas envoyer de facture !";};

[1,(["STR_RECEIVE_NEW_FACTURE","Max_Settings_Facture","Facture_Localization"] call theprogrammer_core_fnc_localize)] remoteExecCall ["life_fnc_broadcast",_to];

[(str _id),(getPlayerUID _to),_objet,_entreprise,_montant,(name _to)] remoteExec ["max_facture_fnc_insertFacture",2];

Dans ton @The_Programmer/addons/billing_system/client/fn_payFacture.sqf, remplace ces lignes :

_fn_find_player = {
    {
        if (_this isEqualTo (getPlayerUID _x)) exitWith {
            _x;
        };
        objNull
    } foreach playableUnits;
};

_player = _from_uid call _fn_find_player;

[] spawn max_facture_fnc_factureListMenu;

life_atmbank = life_atmbank - _price;
[1] call SOCK_fnc_updatePartial;

if (isNull _player) then {
    [_from_uid,_price] remoteExec ["max_facture_fnc_updatePlayer",2];
    if !(isNil "masterpay_script_enable_and_ready") then {
        if (masterpay_script_enable_and_ready) then {
            [player,(["STR_BILLING_SYSTEM_FROM","The_Programmer_Settings_MasterPay","MasterPay_Localization"] call theprogrammer_core_fnc_localize),_price,format [(["STR_BILLING_SYSTEM_DESCRITPION","The_Programmer_Settings_MasterPay","MasterPay_Localization"] call theprogrammer_core_fnc_localize),_id]] spawn masterpay_fnc_updateBank;
        };
    };
} else {
    [0,player,_price,_id] remoteExec ["max_facture_fnc_factureResult",_player];
    [player,_player,_price,"Bank Transfert"] spawn masterpay_fnc_updateBank;
    if !(isNil "masterpay_script_enable_and_ready") then {
        if (masterpay_script_enable_and_ready) then {
            [player,_player,_price,format [(["STR_BILLING_SYSTEM_DESCRITPION","The_Programmer_Settings_MasterPay","MasterPay_Localization"] call theprogrammer_core_fnc_localize),_id]] spawn masterpay_fnc_updateBank;
        };
    };
};

par :

[] spawn max_facture_fnc_factureListMenu;

life_atmbank = life_atmbank - _price;
[1] call SOCK_fnc_updatePartial;

_realEntreprise = objNull;
{
    _entrepriseId = _x select 0;
    if (_entrepriseId isEqualTo _from_uid) exitWith {_realEntreprise = _x select 1;};
} foreach maxence_all_entreprises;

if !(isNull _realEntreprise) then {
    _oldEntACC = _realEntreprise getVariable ["entreprise_bankacc",0];
    _oldEntACC = _oldEntACC + _price;
    _realEntreprise setVariable ["entreprise_bankacc",_oldEntACC,true];
    [(_realEntreprise getVariable ["entreprise_id",0]),5,(_realEntreprise getVariable ["entreprise_bankacc",0])] remoteExecCall ["max_entreprise_fnc_updateEntreprise",2];
    [_realEntreprise,format ["%1 (paiement facture #%2)",(name player),_id],_price,2] remoteExecCall ["max_entreprise_fnc_insertEntrepriseLogs",2];
};

Pour que les employés de l'entreprise voient les factures envoyés par l'entreprise, dans ta mission/The-Programmer/Factures/dialogs/facture_list.hpp, remplace cette ligne :

onbuttonclick = "[(getPlayerUID player)] remoteExec [""max_facture_fnc_getFacturesSended"",2];";

par :

onbuttonclick = "_realEntreprise = player getVariable [""current_entreprise"",objNull]; if (isNull _realEntreprise) exitWith {hint ""Vous n'avez pas d'entreprise, vous ne pouvez pas envoyer de facture !"";}; [str (_realEntreprise getVariable [""entreprise_id"",-1])] remoteExec [""max_facture_fnc_getFacturesSended"",2];";

Dis-moi si ça fonctionne

 

[Teravince]

Error in expression <turesSended.sqf"
_pid = param [0,"",[""]];

if (_pid isEqualTo "">
  Error position: <param [0,"",[""]];
if (_pid isEqualTo "">
  Error Type Number, expected String
File Billing_System\server\fn_getFacturesSended.sqf..., line 17
Error in expression <turesSended.sqf"
 
_pid = param [0,"",[""]];
if (_pid isEqualTo "">
  Error position: <param [0,"",[""]];
if (_pid isEqualTo "">
  Error Type Number, expected String
File Billing_System\server\fn_getFacturesSended.sqf..., line 17

 

[Maxence]

Essaye avec ça dans le bouton plutôt :

onbuttonclick = "_realEntreprise = player getVariable [""current_entreprise"",objNull]; if (isNull _realEntreprise) exitWith {hint ""Vous n'avez pas d'entreprise, vous ne pouvez pas envoyer de facture !"";}; [str (_realEntreprise getVariable [""entreprise_id"",-1])] remoteExec [""max_facture_fnc_getFacturesSended"",2];";