Français Solved Afficher la plaque d'immatriculation des véhicules à distance

[babas59]

Bonjour, j'utilise le script License Plates et le souci est que sur certaines voitures la plaque est par exemple "luke", j'aimerais savoir si c'est possible que quand nous somme en cop et en véhicule on appui sur une touche et que nous sommes à une certaine distance la plaque s'affiche en "hint".
Et pourquoi pas aussi l'afficher en dessous du radar de base.
Merci bonne journée

 

[Snapcoze]

Je ne crois pas que les plaque de Luke sont modifiable.

Et oui c'est possible il faut juste une condition.
ex :

if (side player isEqualTo "WEST" AND vehicle player != player AND ((player distance _car) < _distanceMax)) else {];

 

[babas59]

concrètement j'ai besoin de créer un nouveau fichier sqf ou bien je met ce style de condition dans un existant ?

 

[Maxence]

Hello! Pas forcément besoin de créer un fichier si c'est juste pour hint une variable.
Tu veux mettre quelle touche du clavier ? Et il faut que le joueur regarde la voiture ou il suffit qu'il soit à moins de X mètres d'une voiture ?

Actuellement il y a déjà un hint quand tu fais windows sur le véhicule -> enregistrement

 

[babas59]

j'aimerais mettre la touche "O" et que le joueurs soit à une distance X d'une voiture pas forcément la regarder, que sa fonctionne uniquement si le policier est en voiture.

 

[Maxence]

Alors dans ton fn_keyHandler.sqf, tu peux remplacer l'action actuelle de la touche O :

//O Key
case 24: {
    if (_shift) then {
        if !(soundVolume isEqualTo 1) then {
            1 fadeSound 1;
            systemChat localize "STR_MISC_soundnormal";
        } else {
            1 fadeSound 0.1;
            systemChat localize "STR_MISC_soundfade";
        };
    };
};

par le code suivant :

//O Key
case 24: {
    if (_shift) then {
        if !(soundVolume isEqualTo 1) then {
            1 fadeSound 1;
            systemChat localize "STR_MISC_soundnormal";
        } else {
            1 fadeSound 0.1;
            systemChat localize "STR_MISC_soundfade";
        };
    } else {
        if ((playerSide isEqualTo west) && (vehicle player != player)) then {
            _nearVehicles = nearestObjects [(getPos player),["Car"],25];
            if ((count _nearVehicles) > 1) then {
                _nearestVehicle = _nearVehicles select 1;

                _plate = _nearestVehicle getVariable ["vehicle_info_plate","0"];
                if (_plate isEqualTo "0") then {
                    _plate = (["STR_UNKNOW_PLATE","Max_Settings_Immatriculation","Immatriculation_Localization"] call theprogrammer_core_fnc_localize);
                };

                hint parseText format [(["STR_RESULT_PLATE","Max_Settings_Immatriculation","Immatriculation_Localization"] call theprogrammer_core_fnc_localize),_plate];
            };
        };
    };
};

Il y aura toujours la possibilité de modifier le volume avec SHIFT + O et également la nouvelle fonctionnalité pour les policiers en voiture avec la touche O sans SHIFT.
Tu peux changer la distance de 25 mètres en remplaçant le nombre dans le code

 

[babas59]

alors ça marche bien le problème étant que comme le véhicule le plus proche de est celui dans le quel je suis ça m'affiche ma plaque.
Comment je fais pour mettre aussi sur le radar police en dessous de la vitesse ?

 

[Maxence]

J'ai modifié les lignes 14 et 15 de ma précédente réponse, est-ce que tu peux tester si ça fonctionne maintenant ?

---

Pour le radar, il faut modifier le fn_radar.sqf, en dessous de :

_speed = round speed _vehicle;

ajoute ces lignes :

_plate = _vehicle getVariable ["vehicle_info_plate","0"];
if (_plate isEqualTo "0") then {
    _plate = (["STR_UNKNOW_PLATE","Max_Settings_Immatriculation","Immatriculation_Localization"] call theprogrammer_core_fnc_localize);
};

Et après remplace les deux messages pour afficher la _plate :

case (_speed > 33 && _speed <= 80): {
    hint parseText format ["<t color='#ffffff'><t size='2'><t align='center'>" +(localize "STR_Cop_Radar")+ "<br/><t color='#33CC33'><t align='center'><t size='1'>" +(localize "STR_Cop_VehSpeed"),round  _speed];
};

case (_speed > 80): {
    hint parseText format ["<t color='#ffffff'><t size='2'><t align='center'>" +(localize "STR_Cop_Radar")+ "<br/><t color='#FF0000'><t align='center'><t size='1'>" +(localize "STR_Cop_VehSpeed"),round  _speed];
};

par ceci :

case (_speed > 33 && _speed <= 80): {
    hint parseText format ["<t color='#ffffff'><t size='2'><t align='center'>" +(localize "STR_Cop_Radar")+ "<br/><t color='#33CC33'><t align='center'><t size='1'>" +(localize "STR_Cop_VehSpeed") + "<br/>Plaque d'immatriculation : %2",round  _speed,_plate];
};

case (_speed > 80): {
    hint parseText format ["<t color='#ffffff'><t size='2'><t align='center'>" +(localize "STR_Cop_Radar")+ "<br/><t color='#FF0000'><t align='center'><t size='1'>" +(localize "STR_Cop_VehSpeed") + "<br/>Plaque d'immatriculation : %2",round  _speed,_plate];
};

 

[babas59]

tout est bon merci