English Solved How to improve visibility at night in ordinary servers?

[Paris0]

Ordinary servers can't see things clearly at night without night vision devices, but recently I saw in other servers that they can see things clearly at night without night vision devices. I want to know how to do this.

 

[BastienWolf]

Hello.
I found this on the web. Look at : https://steamcommunity.com/sharedfiles/filedetails/?id=853333870

 

[Maxence]

If you want to put it directly into your mission instead of a mod, you can add at the end of your core/init.sqf :

[] spawn {
    _adjustLight = {
        CHBN_adjustBrightness = CHBN_adjustBrightness max 0 min 1;
        _brightness = if (CHBN_adjustBrightness > 0) then {200 * abs (1 - (2 ^ CHBN_adjustBrightness))} else {0};
        CHBN_light setLightAttenuation [10e10,(30000 / (_brightness max 10e-10)),4.31918e-005,4.31918e-005];
        CHBN_light setLightAmbient CHBN_adjustColor;
    };
    
    waitUntil {time > 0};
    if (missionNamespace getVariable ["CHBN_running",false]) exitWith {systemChat "CHBN script is running. Addon disabled."};
    CHBN_running = true;
    
    CHBN_adjustBrightness = missionNamespace getVariable ["CHBN_adjustBrightness",0.5];
    CHBN_adjustColor = missionNamespace getVariable ["CHBN_adjustColor",[0.3,0.5,1]];

    if (!isNil "CHBN_light") then {deleteVehicle CHBN_light};
    CHBN_light = "#lightpoint" createVehicleLocal [0,0,0];
    CHBN_light setLightBrightness 1;
    CHBN_light setLightDayLight false;
    call _adjustLight;

    for "_i" from 0 to 1 step 0 do {
        _adjustBrightness = CHBN_adjustBrightness;
        _adjustColor = CHBN_adjustColor;
        waitUntil {!(_adjustBrightness isEqualTo CHBN_adjustBrightness) || !(_adjustColor isEqualTo CHBN_adjustColor)};
        call _adjustLight;
    };
};

Code from : https://steamcommunity.com/sharedfiles/filedetails/?id=853333870

 

[Paris0]

Thank you