Français Solved Comment rendre les joueurs visibles uniquement avec un GPS

[Mpoxsx]

Bonjour je voudrais savoir comment faire pour que les joueurs puissent se voir sur la carte uniquement avec un gps et que les personnes qui sont dans un gang soient aussi visible que quand elles ont un gps sur elle pour le moment j'ai modifié la difficulté et je suis invisible sur la carte même quand j'ai un gps sur moi

 

[pos038f]

Bonsoir,

Remplace totalement le fichier fn_civmarkers.sqf dans le dossier core/civilian par

/*

    File: fn_civMarkers.sqf

    Author:



    Description:

    Add markers for civilians in groups.

*/

private ["_markers", "_members"];

_markers = [];

_members = [];



for "_i" from 0 to 1 step 0 do {

    sleep 0.5;

    if (visibleMap) then {

        _members = units (group player);

        {

            if (!(_x isEqualTo player) && ("ItemGPS" in (assignedItems _X)) && ("ItemGPS" in (assignedItems player))) then {

                _marker = createMarkerLocal [format ["%1_marker", _x], visiblePosition _x];

                _marker setMarkerColorLocal "ColorCivilian";

                _marker setMarkerTypeLocal "Mil_dot";

                _marker setMarkerTextLocal format ["%1", _x getVariable ["realname", name _x]];

                _markers pushBack [_marker, _x];

            };

        } forEach _members;
        
        //Bloc si vous voulez que chaque joueur se voit sur la carte (avec le nom) s'ils ont un GPS
        
        if ("ItemGPS" in (assignedItems player)) then {

            _me = createMarkerLocal [format ["%1_marker",player],visiblePosition player];

            _me setMarkerColorLocal "ColorRed";

            _me setMarkerTypeLocal "Mil_dot";

            _markers pushBack [_me,player];

        };
        
        while {visibleMap} do {

            {

                private ["_unit"];

                _unit = _x select 1;

                if (!isNil "_unit" && !isNull _unit) then {

                    (_x select 0) setMarkerPosLocal (visiblePosition _unit);

                };

            } forEach _markers;

            if (!visibleMap) exitWith { };

            sleep 0.02;

        };



        { deleteMarkerLocal (_x select 0); } forEach _markers;

        _markers = [];

        _members = [];

    };

};

Pour ce qui est de la difficulté, je me rappel plus de quel "class" il faut modifier pour cela.

 

[Mpoxsx]

Bonjour merci beaucoup pour ce qui visibilité entre membre du gang cella fonctionne parfaitement je cherche maintenant comment faire pour que je puisse me voir sur la carte quand j'ai un gps sur moi

 

[Maxence]

Eh bien tu peux ajouter en dessous de } forEach _members; dans la modification de P pos038f :

if ("ItemGPS" in (assignedItems player)) then {
    _me = createMarkerLocal [format ["%1_marker",player],visiblePosition player];
    _me setMarkerColorLocal "ColorRed";
    _me setMarkerTypeLocal "Mil_dot";
    _markers pushBack [_me,player];
};

 

[Mpoxsx]

Nickel ça marche merci beaucoup

 

[pos038f]

J'ai modifier ma répons pour contenir la partie à Maxence

 

[Mpoxsx]

merci