Français Solved Comment changer la touche d'ouverture du Radial Menu?

[Robinox]

Bonjour, j'aimerais que le Radial Menu s'ouvre avec la touche control au lieux de Windows, comment je pourrais f aire? Ou comment je change la touche?

 

[Maxence]

Salut !

Il faut l'enlever de la touche windows pour commencer, dans le fn_actionKeyHandler.sqf
Et l'ajouter sur la touche CTRL dans le fn_keyHandler.sqf

Si tu ne sais pas comment faire, tu peux m'envoyer ces deux fichiers

 

[Robinox]

Voici mon fn_actionKeyHandler.sqf : https://paste-me.net/ebonu
Voici mon fn_keyHandler.sqf : https://paste-me.net/abitu

 

[Maxence]

Dans ton fn_actionKeyHandler.sqf supprime ces 4 parties :

if (playerSide isEqualTo west && {player getVariable ["isEscorting",false]}) exitWith {
     ["cop_interaction"] spawn CBX_fnc_openInteraction;
};

if (_curObject isKindOf "House_F" && {player distance _curObject < 12} || ((nearestObject [_pos,"Land_Dome_Big_F"]) isEqualTo _curObject || (nearestObject [_pos,_vaultHouse]) isEqualTo _curObject)) exitWith {
    switch (side player) do {
    case civilian: {["house_menu"] spawn CBX_fnc_openInteraction;};
    case west: {["cop_house_menu"] spawn CBX_fnc_openInteraction;};
    default {}; };
};

if (!dialog && playerSide isEqualTo west) then {
    ["cop_interaction"] spawn CBX_fnc_openInteraction;
};

if (!dialog) then {
    if (player distance _curObject < ((boundingBox _curObject select 1) select 0)+2 && (!(player getVariable ["restrained",false])) && (!(player getVariable ["playerSurrender",false])) && !life_isknocked && !life_istazed) then {
        ['vehicle_menu'] spawn CBX_fnc_openInteraction;
    };
};

Dans ton fn_keyHandler.sqf, trouve cette ligne :

_interruptionKeys = [17,30,31,32];

Et ajoute en dessous :

_exit = false;
if (_ctrlKey) then {
    if (playerSide isEqualTo west) then {
        if (player getVariable ["isEscorting",false]) then {
            ["cop_interaction"] spawn CBX_fnc_openInteraction;
            _exit = true;
        } else {
            if ((isPlayer cursorObject) && (cursorObject isKindOf "Man") && !dialog) then {
                ["cop_interaction"] spawn CBX_fnc_openInteraction;
                _exit = true;
            };
        };
    };

    if (_exit) exitWith {};

    if ((cursorObject isKindOf "House_F") && ((player distance cursorObject) < 12)) then {
        switch (side player) do {
            case civilian: {["house_menu"] spawn CBX_fnc_openInteraction;};
            case west: {["cop_house_menu"] spawn CBX_fnc_openInteraction;};
            default {};
        };
        _exit = true;
    };

    if (_exit) exitWith {};

    if ((cursorObject isKindOf "landVehicle") || (cursorObject isKindOf "Ship") || (cursorObject isKindOf "Air")) then {
        if !(dialog) then {
            if ((player distance cursorObject) < ((boundingBox cursorObject select 1) select 0)+2 && (!(player getVariable ["restrained",false])) && (!(player getVariable ["playerSurrender",false])) && !life_isknocked && !life_istazed) then {
                ['vehicle_menu'] spawn CBX_fnc_openInteraction;
                _exit = true;
            };
        };
    };
};
if (_exit) exitWith {};

 

[Robinox]

Merci