Français Augmenter le nombre de tortues

[Nesta]

Bonjour, j'ai eu beau retouché les fichiers lié a la pêche pour augmenter le spawn de tortue mais rien n'y fait. Le système du filet de pêche n'attrapera jamais de tortue. Donc pourquoi ne pas crée un fichier ressemblant a celui de la chasse qui fait spawn des animaux.

Crée un fichier fn_turtleZone dans votre dossier Functions/Systems de votre life server :

/*
    File: fn_turtleZone.sqf
    Author: Bryan "Tonic" Boardwine
    Modified: Nesta

    Description:
    Spawn de tortues.
*/

private ["_animalList","_dist","_radius","_zoneName","_unitsNear","_animalsActive"];
params [
        ["_zoneName","",[""]],
        ["_maxAnimals",50,[0]]
];

if (_zoneName isEqualTo "") exitWith {};
_animalList = ["Turtle_F"];
_radius = (getMarkerSize _zoneName) select 0;
_dist = _radius + 50;
_zone = getMarkerPos _zoneName;

if (!isNil "animals" && {!(count animals isEqualTo 0)}) then {
    _maxAnimals = _maxAnimals - count(animals);
} else {
    animals = [];
};

_unitsNear = false;
_animalsActive = false;
for "_i" from 0 to 1 step 0 do {
    {if ((_x distance _zone) < _dist) exitWith {_unitsNear = true;}; _unitsNear = false;} forEach playableUnits;
    if (_unitsNear && !_animalsActive) then {
        _animalsActive = true;
        for "_i" from 1 to _maxAnimals do {
            _animalClass = selectRandom _animalList;
            _position = [((_zone select 0) - _radius + random (_radius * 2)), ((_zone select 1) - _radius + random (_radius * 2)),0];
            _animal = createAgent [_animalClass,_position,[],0,"FORM"];
            _animal setDir (random 360);
            animals pushBack _animal;
        };
    } else {
        if (!_unitsNear && _animalsActive) then {
            {deleteVehicle _x;} forEach animals;
            animals = [];
            _animalsActive = false;
        };
    };
    uiSleep (3 + random 2);
    _maxAnimals = param [1,50,[0]];
};

Dans le config.cpp (life server) dans la "class Systems" ajoutez:

class turtleZone {};

en dessous de :

class huntingZone {};

Dans le fichier init.sqf de votre life serveur ajoutez :

aiSpawn = ["turtle_zone",50] spawn TON_fnc_turtleZone;

en dessous de

aiSpawn = ["hunting_zone",30] spawn TON_fnc_huntingZone;

Dans l'init de votre marqueur qui définira votre zone de pêche ajoutez : turtle_zone